Shaders from angrybots

So amid the fiasco with angrybots yesterday I did notice that whatever shader they had overriding bumped diffuse looked spectacular. Does anyone know where I can get that without downloading angrybots again?

If you need simple Diffuse shader with bump map and specular simply create it. It is possible to look at an example in Unity help. Or I will write below a simple code:

 Shader "Custom/DifBumpSpec" {
  Properties {
   _MainTex ("Texture", 2D) = "white" {}
   _BumpMap ("Bumpmap", 2D) = "bump" {}
  }
  SubShader {
   Tags { "RenderType" = "Opaque" }
   CGPROGRAM
   #pragma surface surf SimpleSpecular
    
   half4 LightingSimpleSpecular (SurfaceOutput s, half3 lightDir, half3 viewDir, half atten) {
    half3 h = normalize (lightDir + viewDir);

    half diff = max (0, dot (s.Normal, lightDir));

    float nh = max (0, dot (s.Normal, h));
    float spec = pow (nh, 48.0);

    half4 c;
    c.rgb = (s.Albedo * _LightColor0.rgb * diff + _LightColor0.rgb * spec) * (atten * 2);
    c.a = s.Alpha;
    return c;
   }

   struct Input {
    float2 uv_MainTex;
    float2 uv_BumpMap;
   };

   sampler2D _MainTex;
   sampler2D _BumpMap;
   void surf (Input IN, inout SurfaceOutput o) {
    float4 c = tex2D (_MainTex, IN.uv_MainTex);
    o.Albedo = c.rgb;
    o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
    o.Alpha = c.a;
   }
   ENDCG
  } 
  Fallback "Diffuse"
 }

I hope that it will help you.