x


additive particle shader

hey

At the moment I'm using the particles/additive shader in a material to be used with a particle effect I'm making. However I want to make this shader not effected by fog. I know how to do that but I can't find the shader code for the particles/additive shader. I've downloaded some of the shader codes from this webpage but none of the ones I've download have the shader code for particles/additive. (I've tried unity 4, 3.5.7 and 3 shaders). Is there a place if any where I can get the code for this shader.

Thanks

more ▼

asked Dec 31 '12 at 10:41 PM

SP0KK0 gravatar image

SP0KK0
198 9 13 14

(comments are locked)
10|3000 characters needed characters left

2 answers: sort voted first

I have the Particles/Additive shader in the package I downloaded, but I don't remember the exact place I got it from...

Anyways, here you go:

Shader "Particles/Additive" {
Properties {
    _TintColor ("Tint Color", Color) = (0.5,0.5,0.5,0.5)
    _MainTex ("Particle Texture", 2D) = "white" {}
    _InvFade ("Soft Particles Factor", Range(0.01,3.0)) = 1.0
}

Category {
    Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" }
    Blend SrcAlpha One
    AlphaTest Greater .01
    ColorMask RGB
    Cull Off Lighting Off ZWrite Off Fog { Color (0,0,0,0) }
    BindChannels {
       Bind "Color", color
       Bind "Vertex", vertex
       Bind "TexCoord", texcoord
    }

    // ---- Fragment program cards
    SubShader {
       Pass {

         CGPROGRAM
         #pragma vertex vert
         #pragma fragment frag
         #pragma fragmentoption ARB_precision_hint_fastest
         #pragma multi_compile_particles

         #include "UnityCG.cginc"

         sampler2D _MainTex;
         fixed4 _TintColor;

         struct appdata_t {
          float4 vertex : POSITION;
          fixed4 color : COLOR;
          float2 texcoord : TEXCOORD0;
         };

         struct v2f {
          float4 vertex : POSITION;
          fixed4 color : COLOR;
          float2 texcoord : TEXCOORD0;
          #ifdef SOFTPARTICLES_ON
          float4 projPos : TEXCOORD1;
          #endif
         };

         float4 _MainTex_ST;

         v2f vert (appdata_t v)
         {
          v2f o;
          o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
          #ifdef SOFTPARTICLES_ON
          o.projPos = ComputeScreenPos (o.vertex);
          COMPUTE_EYEDEPTH(o.projPos.z);
          #endif
          o.color = v.color;
          o.texcoord = TRANSFORM_TEX(v.texcoord,_MainTex);
          return o;
         }

         sampler2D _CameraDepthTexture;
         float _InvFade;

         fixed4 frag (v2f i) : COLOR
         {
          #ifdef SOFTPARTICLES_ON
          float sceneZ = LinearEyeDepth (UNITY_SAMPLE_DEPTH(tex2Dproj(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos))));
          float partZ = i.projPos.z;
          float fade = saturate (_InvFade * (sceneZ-partZ));
          i.color.a *= fade;
          #endif

          return 2.0f * i.color * _TintColor * tex2D(_MainTex, i.texcoord);
         }
         ENDCG 
       }
    }  

    // ---- Dual texture cards
    SubShader {
       Pass {
         SetTexture [_MainTex] {
          constantColor [_TintColor]
          combine constant * primary
         }
         SetTexture [_MainTex] {
          combine texture * previous DOUBLE
         }
       }
    }

    // ---- Single texture cards (does not do color tint)
    SubShader {
       Pass {
         SetTexture [_MainTex] {
          combine texture * primary
         }
       }
    }
}
}
more ▼

answered Dec 31 '12 at 11:04 PM

Piflik gravatar image

Piflik
5.7k 27 31 52

(comments are locked)
10|3000 characters needed characters left

(At least in Unity 3.5.6) "particles/additive" is called "Particle Add.shader" in the "DefaultResources" folder. http://unity3d.com/unity/download/archive

more ▼

answered Dec 31 '12 at 11:07 PM

jogo13 gravatar image

jogo13
581 1 3

cheers guys, thanks, that's just what I needed

Dec 31 '12 at 11:09 PM SP0KK0
(comments are locked)
10|3000 characters needed characters left
Your answer
toggle preview:

Up to 2 attachments (including images) can be used with a maximum of 524.3 kB each and 1.0 MB total.

Follow this question

By Email:

Once you sign in you will be able to subscribe for any updates here

By RSS:

Answers

Answers and Comments

Topics:

x2588
x925
x56

asked: Dec 31 '12 at 10:41 PM

Seen: 5868 times

Last Updated: Dec 31 '12 at 11:09 PM